Ticket #1521: bug.pir

.sub 'main' :main
    # Set up the stack of continuations, representing our choice points.
    $P0 = new 'ResizablePMCArray'
    set_global 'ccs', $P0

    # Our exit strategy. When no more options are left to backtrack over, exit.
    $P1 = new 'Continuation'
    set_addr $P1, done

    push $P0, $P1 # Put the continuation on the stack.

    $S0 = choose("foo", "bar", "blech")
    $S0 = "main:   " . $S0
    say $S0

    'backtrack'()

  done:
    say "Done."
.end

.sub 'choose'
    .param pmc options :slurpy

    .local pmc value

    if options goto got_options
    'backtrack'() # Out of options. Backtrack.
  got_options:

    value = shift options

    # Create a choice point and store it on the stack.
    $P0 = new 'Continuation'
    set_addr $P0, recurse
    $P1 = get_global 'ccs'
    push $P1, $P0

    $S0 = value
    $S0 = "choose: " . $S0
    say $S0

    .return (value)

  recurse:
    # On backtrack, recurse on the reduced list of options.
    #.tailcall 'choose'(options :flat)
    .tailcall 'choose'(options :flat)
.end

.sub 'backtrack'
    $P0 = get_global 'ccs' # Get the stack.
    $P1 = pop $P0        # Get the next continuation in line.
    $P1()                  # Invoke the continuation.
.end